Arduino: MQTT

MQTT e Arduino

O suporte para MQTT para Arduíno é provido por uma biblioteca que pode ser obtida em: https://github.com/knolleary/pubsubclient .

Uma boa descrição do uso da biblioteca PubSubClient.h pode ser encontrada em:

Para interagir com a rede é necessário um shild Ethernet colocado sobre a placa Arduíno.

Limitações do MQTT para Arduíno

• Suporta somente publicações com QoS=0 e subscrições com QoS=0 ou QoS=1.
• Suporta somente CleanSessions devido a limitação de memória.
• Tamanho máximo de mensagem com 128 bytes por default.
• Intervalo de keep alive de 15 s por default.

  Os dois últimos parâmetros podem ser alterados na biblioteca PubSubClient.h:

  MQTT_MAX_PACKET_SIZE

  MQTT_KEEPALIVE

Hardware compatível

• Shield Ethernet
• Arduíno Ethernet
• Arduíno Yun
• Arduíno Wifi
• ESP8266
• ESP32

Exemplo: MQTT e Arduino

/*            
 Baseado no exemplo da bilbioteca PubSubClient.h: Basic MQTT example

 Exemplo: MQTT com Arduíno/Shield Ethernet e Mosquitto: 
 Anunciar status do Arduino, receber comando para led e publicar status do led.

 Este sketch demonstra a comunicação de um Arduino com um brocker Mosquitto usando MQTT:
  - conecta ao brocker e informa lastWill para o tópico "status" com mensagem "off-line"
    (será publicada caso o Arduino seja desconectado involuntariamente);
  - publica para o tópico "status" a mensagem  "on-line" anunciando que está ativo;
  - subscreve o tópico "led" para receber comandos para um led;
  - caso receba mensagem para o tópico "led", aciona o led conforme comando recebido
    e publica para o tópico "ledStatus" o estado do led após o comando.
*/

#include <SPI.h>
#include <Ethernet.h>
#include <PubSubClient.h>

// Endereçamento IP utilizado para o cliente e servidor
byte mac[]    = { 0xDE, 0xED, 0xBA, 0xFE, 0xFE, 0xED };
IPAddress ip(192, 168, 0, 30);
IPAddress server(192, 168, 0, 13);

EthernetClient ethClient;
PubSubClient client(ethClient);

//Função callback chamada quando uma mensagem for recebida para subscrições:
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i=0;i<length;i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
  //comanda o "led" e publica "ledStatus"
  if (length == 2 and !strncmp((char*)payload, "on", length)) {
      digitalWrite(LED_BUILTIN, HIGH);
      client.publish("ledStatus", "ON");
  } else if (length == 3 and !strncmp((char*)payload, "off", length)) {
      digitalWrite(LED_BUILTIN, LOW);
      client.publish("ledStatus", "OFF");
  } else {
      client.publish("ledStatus", "NOT CHANGE");
  }
}

void setup()
{
  Serial.begin(57600);

  client.setServer(server, 1883);
  client.setCallback(callback);

  Ethernet.begin(mac, ip);
  delay(5000); // Allow the hardware to sort itself out
  
  delay(10000);
}

void loop(){
  // Aguarda conexão    
  while (!client.connected()) {

    Serial.print("Attempting MQTT connection...");

    //Mensagem lastWill
    byte willQoS = 0;
    const char* willTopic = "status";
    const char* willMessage = "off-line";
    boolean willRetain = true;
    //Conexão
    if (client.connect("arduinoClient", willTopic, willQoS, willRetain, willMessage)) {
      Serial.println("connected");
      //Uma vez conectado publica status
      char* message = "on-line";
      int length = strlen(message);
      boolean retained = true; //Retain message
      client.publish("status", (byte*)message, length, retained);
      // ... and resubscribe
      client.subscribe("led");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
  //Uma vez conectado client.loop() deve ser chamada periodicamente para manter conexão
  //e aguardar recebimento de mensagens
  client.loop();
}

Referências

Evandro.cantu (discussão) 10h27min de 16 de abril de 2020 (-03)